import org.h2.tools.Console;

buildscript {

    repositories {
		mavenCentral()
	}

	dependencies {
		classpath group: "com.h2database", name: "h2", version: "1.4.200"
	}
}

plugins {
	id "war"
	id "application"
}

repositories {
	mavenCentral()
}

dependencies {
	providedCompile group: "javax.servlet", name: "javax.servlet-api", version: "4.0.1"

	// jetty 10 supports servlet 4
	def jettyVer = "10.+"

	implementation group: "org.eclipse.jetty", name: "jetty-webapp", version: jettyVer
	implementation group: "org.eclipse.jetty", name: "jetty-annotations", version: jettyVer
	implementation group: "org.eclipse.jetty", name: "apache-jsp", version: jettyVer
	implementation group: "org.eclipse.jetty", name: "jetty-slf4j-impl", version: jettyVer
	implementation group: "com.h2database", name: "h2", version: "1.4.200"
	implementation group: "ch.qos.logback", name: "logback-classic", version: "1.2.5"
}

war {
	// add db to WAR
	from 'db'
}

run {
	dependsOn war
}

tasks.register("db") {
	doLast {
		new org.h2.tools.Console().runTool("-user", "sa", "-url", "jdbc:h2:${projectDir}/db/db/users;AUTO_SERVER=TRUE;IFEXISTS=TRUE");
	}
}

mainClassName = "Start"